Example: article2html.xsl, Part II

<xsl:template match="abstract">
<table width="80%" align="center"><tr><td>
<h4>Abstract</h4>
<xsl:apply-templates/>
</td></tr></table>
</xsl:template>

<xsl:template match="section">
<h3><a name="{generate-id()}">
  <xsl:number format="1. "/>
  <xsl:apply-templates select="title" mode="raw"/>
</a></h3>
<xsl:apply-templates/>
</xsl:template>

<xsl:template match="subsection">
<h4><a name="{generate-id()}">
  <xsl:number level="multiple" count="section|subsection" format="1.1 "/>
  <xsl:apply-templates select="title" mode="raw"/>
</a></h4>
<xsl:apply-templates/>
</xsl:template>

<xsl:template match="ref[@section]">
<a href="#{generate-id(key('idkey',@section))}">
  <xsl:for-each select="key('idkey',@section)">
    <xsl:number level="single" count="section" format="1"/>
  </xsl:for-each>
</a>
</xsl:template>

<xsl:template match="ref[@subsection]">
<a href="#{generate-id(key('idkey',@subsection))}">
  <xsl:for-each select="key('idkey',@subsection)">
    <xsl:number level="multiple" count="section|subsection" format="1.1"/>
  </xsl:for-each>
</a>
</xsl:template>